home *** CD-ROM | disk | FTP | other *** search
/ The CICA Windows Explosion! / The CICA Windows Explosion! - Disc 2.iso / nt / emacssrc.zip / EMACSSRC.TAR / emacs-19.17 / lisp / gud.el < prev    next >
Lisp/Scheme  |  1993-07-23  |  34KB  |  953 lines
  1. ;;; gud.el --- Grand Unified Debugger mode for gdb, sdb, dbx, or xdb
  2. ;;;            under Emacs
  3.  
  4. ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
  5. ;; Version: 1.3
  6. ;; Keywords: unix, tools
  7.  
  8. ;; Copyright (C) 1992, 1993 Free Software Foundation, Inc.
  9.  
  10. ;; This file is part of GNU Emacs.
  11.  
  12. ;; GNU Emacs is free software; you can redistribute it and/or modify
  13. ;; it under the terms of the GNU General Public License as published by
  14. ;; the Free Software Foundation; either version 2, or (at your option)
  15. ;; any later version.
  16.  
  17. ;; GNU Emacs is distributed in the hope that it will be useful,
  18. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20. ;; GNU General Public License for more details.
  21.  
  22. ;; You should have received a copy of the GNU General Public License
  23. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25.  
  26. ;;; Commentary:
  27.  
  28. ;; The ancestral gdb.el was by W. Schelter <wfs@rascal.ics.utexas.edu>
  29. ;; It was later rewritten by rms.  Some ideas were due to Masanobu. 
  30. ;; Grand Unification (sdb/dbx support) by Eric S. Raymond <esr@thyrsus.com>
  31. ;; The overloading code was then rewritten by Barry Warsaw <bwarsaw@cen.com>,
  32. ;; who also hacked the mode to use comint.el.  Shane Hartman <shane@spr.com>
  33. ;; added support for xdb (HPUX debugger).
  34.  
  35. ;;; Code:
  36.  
  37. (require 'comint)
  38. (require 'etags)
  39.  
  40. ;; ======================================================================
  41. ;; GUD commands must be visible in C buffers visited by GUD
  42.  
  43. (defvar gud-key-prefix "\C-x\C-a"
  44.   "Prefix of all GUD commands valid in C buffers.")
  45.  
  46. (global-set-key (concat gud-key-prefix "\C-l") 'gud-refresh)
  47. (global-set-key "\C-x " 'gud-break)    ;; backward compatibility hack
  48.  
  49. ;; ======================================================================
  50. ;; the overloading mechanism
  51.  
  52. (defun gud-overload-functions (gud-overload-alist)
  53.   "Overload functions defined in GUD-OVERLOAD-ALIST.
  54. This association list has elements of the form
  55.      (ORIGINAL-FUNCTION-NAME  OVERLOAD-FUNCTION)"
  56.   (mapcar
  57.    (function (lambda (p) (fset (car p) (symbol-function (cdr p)))))
  58.    gud-overload-alist))
  59.  
  60. (defun gud-massage-args (file args)
  61.   (error "GUD not properly entered."))
  62.  
  63. (defun gud-marker-filter (str)
  64.   (error "GUD not properly entered."))
  65.  
  66. (defun gud-find-file (f)
  67.   (error "GUD not properly entered."))
  68.  
  69. ;; ======================================================================
  70. ;; command definition
  71.  
  72. ;; This macro is used below to define some basic debugger interface commands.
  73. ;; Of course you may use `gud-def' with any other debugger command, including
  74. ;; user defined ones.
  75.  
  76. ;; A macro call like (gud-def FUNC NAME KEY DOC) expands to a form
  77. ;; which defines FUNC to send the command NAME to the debugger, gives
  78. ;; it the docstring DOC, and binds that function to KEY in the GUD
  79. ;; major mode.  The function is also bound in the global keymap with the
  80. ;; GUD prefix.
  81.  
  82. (defmacro gud-def (func cmd key &optional doc)
  83.   "Define FUNC to be a command sending STR and bound to KEY, with
  84. optional doc string DOC.  Certain %-escapes in the string arguments
  85. are interpreted specially if present.  These are:
  86.  
  87.   %f    name of current source file. 
  88.   %l    number of current source line
  89.   %e    text of the C lvalue or function-call expression surrounding point.
  90.   %a    text of the hexadecimal address surrounding point
  91.   %p    prefix argument to the command (if any) as a number
  92.  
  93.   The `current' source file is the file of the current buffer (if
  94. we're in a C file) or the source file current at the last break or
  95. step (if we're in the GUD buffer).
  96.   The `current' line is that of the current buffer (if we're in a
  97. source file) or the source line number at the last break or step (if
  98. we're in the GUD buffer)."
  99.   (list 'progn
  100.     (list 'defun func '(arg)
  101.           (or doc "")
  102.           '(interactive "p")
  103.           (list 'gud-call cmd 'arg))
  104.     (if key
  105.         (list 'define-key
  106.           '(current-local-map)
  107.           (concat "\C-c" key)
  108.           (list 'quote func)))
  109.     (if key
  110.         (list 'global-set-key
  111.           (list 'concat 'gud-key-prefix key)
  112.           (list 'quote func)))))
  113.  
  114. ;; Where gud-display-frame should put the debugging arrow.  This is
  115. ;; set by the marker-filter, which scans the debugger's output for
  116. ;; indications of the current program counter.
  117. (defvar gud-last-frame nil)
  118.  
  119. ;; Used by gud-refresh, which should cause gud-display-frame to redisplay
  120. ;; the last frame, even if it's been called before and gud-last-frame has
  121. ;; been set to nil.
  122. (defvar gud-last-last-frame)
  123.  
  124. ;; All debugger-specific information is collected here.
  125. ;; Here's how it works, in case you ever need to add a debugger to the mode.
  126. ;;
  127. ;; Each entry must define the following at startup:
  128. ;;
  129. ;;<name>
  130. ;; comint-prompt-regexp
  131. ;; gud-<name>-massage-args
  132. ;; gud-<name>-marker-filter
  133. ;; gud-<name>-find-file
  134. ;;
  135. ;; The job of the massage-args method is to modify the given list of
  136. ;; debugger arguments before running the debugger.
  137. ;;
  138. ;; The job of the marker-filter method is to detect file/line markers in
  139. ;; strings and set the global gud-last-frame to indicate what display
  140. ;; action (if any) should be triggered by the marker.  Note that only
  141. ;; whatever the method *returns* is displayed in the buffer; thus, you
  142. ;; can filter the debugger's output, interpreting some and passing on
  143. ;; the rest.
  144. ;;
  145. ;; The job of the find-file method is to visit and return the buffer indicated
  146. ;; by the car of gud-tag-frame.  This may be a file name, a tag name, or
  147. ;; something else.
  148.  
  149. ;; ======================================================================
  150. ;; gdb functions
  151.  
  152. ;;; History of argument lists passed to gdb.
  153. (defvar gud-gdb-history nil)
  154.  
  155. (defun gud-gdb-massage-args (file args)
  156.   (cons "-fullname" (cons file args)))
  157.  
  158. (defun gud-gdb-marker-filter (string)
  159.   (if (string-match  "\032\032\\([^:\n]*\\):\\([0-9]*\\):.*\n" string)
  160.       (progn
  161.     (setq gud-last-frame
  162.           (cons
  163.            (substring string (match-beginning 1) (match-end 1))
  164.            (string-to-int
  165.         (substring string (match-beginning 2) (match-end 2)))))
  166.     ;; this computation means the ^Z^Z-initiated marker in the
  167.     ;; input string is never emitted.
  168.     (concat
  169.      (substring string 0 (match-beginning 0))
  170.      (substring string (match-end 0))
  171.      ))
  172.     string))
  173.  
  174. (defun gud-gdb-find-file (f)
  175.   (find-file-noselect f))
  176.  
  177. ;;;###autoload
  178. (defun gdb (command-line)
  179.   "Run gdb on program FILE in buffer *gud-FILE*.
  180. The directory containing FILE becomes the initial working directory
  181. and source-file directory for your debugger."
  182.   (interactive
  183.    (list (read-from-minibuffer "Run gdb (like this): "
  184.                    (if (consp gud-gdb-history)
  185.                    (car gud-gdb-history)
  186.                  "gdb ")
  187.                    nil nil
  188.                    '(gud-gdb-history . 1))))
  189.   (gud-overload-functions '((gud-massage-args . gud-gdb-massage-args)
  190.                 (gud-marker-filter . gud-gdb-marker-filter)
  191.                 (gud-find-file . gud-gdb-find-file)
  192.                 ))
  193.  
  194.   (gud-common-init command-line)
  195.  
  196.   (gud-def gud-break  "break %f:%l"  "\C-b" "Set breakpoint at current line.")
  197.   (gud-def gud-tbreak "tbreak %f:%l" "\C-t" "Set breakpoint at current line.")
  198.   (gud-def gud-remove "clear %l"     "\C-d" "Remove breakpoint at current line")
  199.   (gud-def gud-step   "step %p"      "\C-s" "Step one source line with display.")
  200.   (gud-def gud-stepi  "stepi %p"     "\C-i" "Step one instruction with display.")
  201.   (gud-def gud-next   "next %p"      "\C-n" "Step one line (skip functions).")
  202.   (gud-def gud-cont   "cont"         "\C-r" "Continue with display.")
  203.   (gud-def gud-finish "finish"       "\C-f" "Finish executing current function.")
  204.   (gud-def gud-up     "up %p"        "<" "Up N stack frames (numeric arg).")
  205.   (gud-def gud-down   "down %p"      ">" "Down N stack frames (numeric arg).")
  206.   (gud-def gud-print  "print %e"     "\C-p" "Evaluate C expression at point.")
  207.  
  208.   (setq comint-prompt-regexp "^(.*gdb[+]?) *")
  209.   (run-hooks 'gdb-mode-hook)
  210.   )
  211.  
  212.  
  213. ;; ======================================================================
  214. ;; sdb functions
  215.  
  216. ;;; History of argument lists passed to sdb.
  217. (defvar gud-sdb-history nil)
  218.  
  219. (defvar gud-sdb-needs-tags (not (file-exists-p "/var"))
  220.   "If nil, we're on a System V Release 4 and don't need the tags hack.")
  221.  
  222. (defvar gud-sdb-lastfile nil)
  223.  
  224. (defun gud-sdb-massage-args (file args)
  225.   (cons file args))
  226.  
  227. (defun gud-sdb-marker-filter (string)
  228.   (cond 
  229.    ;; System V Release 3.2 uses this format
  230.    ((string-match "\\(^0x\\w* in \\|^\\|\n\\)\\([^:\n]*\\):\\([0-9]*\\):.*\n"
  231.             string)
  232.     (setq gud-last-frame
  233.       (cons
  234.        (substring string (match-beginning 2) (match-end 2))
  235.        (string-to-int 
  236.         (substring string (match-beginning 3) (match-end 3))))))
  237.    ;; System V Release 4.0 
  238.    ((string-match "^\\(BREAKPOINT\\|STEPPED\\) process [0-9]+ function [^ ]+ in \\(.+\\)\n"
  239.                string)
  240.     (setq gud-sdb-lastfile
  241.       (substring string (match-beginning 2) (match-end 2))))
  242.    ((and gud-sdb-lastfile (string-match "^\\([0-9]+\\):" string))
  243.      (setq gud-last-frame
  244.            (cons
  245.         gud-sdb-lastfile
  246.         (string-to-int 
  247.          (substring string (match-beginning 1) (match-end 1))))))
  248.    (t 
  249.     (setq gud-sdb-lastfile nil)))
  250.   string)
  251.  
  252. (defun gud-sdb-find-file (f)
  253.   (if gud-sdb-needs-tags
  254.       (find-tag-noselect f)
  255.     (find-file-noselect f)))
  256.  
  257. ;;;###autoload
  258. (defun sdb (command-line)
  259.   "Run sdb on program FILE in buffer *gud-FILE*.
  260. The directory containing FILE becomes the initial working directory
  261. and source-file directory for your debugger."
  262.   (interactive
  263.    (list (read-from-minibuffer "Run sdb (like this): "
  264.                    (if (consp gud-sdb-history)
  265.                    (car gud-sdb-history)
  266.                  "sdb ")
  267.                    nil nil
  268.                    '(gud-sdb-history . 1))))
  269.   (if (and gud-sdb-needs-tags
  270.        (not (and (boundp 'tags-file-name) (file-exists-p tags-file-name))))
  271.       (error "The sdb support requires a valid tags table to work."))
  272.   (gud-overload-functions '((gud-massage-args . gud-sdb-massage-args)
  273.                 (gud-marker-filter . gud-sdb-marker-filter)
  274.                 (gud-find-file . gud-sdb-find-file)
  275.                 ))
  276.  
  277.   (gud-common-init command-line)
  278.  
  279.   (gud-def gud-break  "%l b" "\C-b"   "Set breakpoint at current line.")
  280.   (gud-def gud-tbreak "%l c" "\C-t"   "Set temporary breakpoint at current line.")
  281.   (gud-def gud-remove "%l d" "\C-d"   "Remove breakpoint at current line")
  282.   (gud-def gud-step   "s %p" "\C-s"   "Step one source line with display.")
  283.   (gud-def gud-stepi  "i %p" "\C-i"   "Step one instruction with display.")
  284.   (gud-def gud-next   "S %p" "\C-n"   "Step one line (skip functions).")
  285.   (gud-def gud-cont   "c"    "\C-r"   "Continue with display.")
  286.   (gud-def gud-print  "%e/"  "\C-p"   "Evaluate C expression at point.")
  287.  
  288.   (setq comint-prompt-regexp  "\\(^\\|\n\\)\\*")
  289.   (run-hooks 'sdb-mode-hook)
  290.   )
  291.  
  292. ;; ======================================================================
  293. ;; dbx functions
  294.  
  295. ;;; History of argument lists passed to dbx.
  296. (defvar gud-dbx-history nil)
  297.  
  298. (defun gud-dbx-massage-args (file args)
  299.   (cons file args))
  300.  
  301. (defun gud-dbx-marker-filter (string)
  302.   (if (string-match
  303.        "stopped in .* at line \\([0-9]*\\) in file \"\\([^\"]*\\)\"" string)
  304.       (setq gud-last-frame
  305.         (cons
  306.          (substring string (match-beginning 2) (match-end 2))
  307.          (string-to-int 
  308.           (substring string (match-beginning 1) (match-end 1))))))
  309.   string)
  310.  
  311. (defun gud-dbx-find-file (f)
  312.   (find-file-noselect f))
  313.  
  314. ;;;###autoload
  315. (defun dbx (command-line)
  316.   "Run dbx on program FILE in buffer *gud-FILE*.
  317. The directory containing FILE becomes the initial working directory
  318. and source-file directory for your debugger."
  319.   (interactive
  320.    (list (read-from-minibuffer "Run dbx (like this): "
  321.                    (if (consp gud-dbx-history)
  322.                    (car gud-dbx-history)
  323.                  "dbx ")
  324.                    nil nil
  325.                    '(gud-dbx-history . 1))))
  326.   (gud-overload-functions '((gud-massage-args . gud-dbx-massage-args)
  327.                 (gud-marker-filter . gud-dbx-marker-filter)
  328.                 (gud-find-file . gud-dbx-find-file)
  329.                 ))
  330.  
  331.   (gud-common-init command-line)
  332.  
  333.   (gud-def gud-break  "stop at \"%f\":%l"
  334.                      "\C-b" "Set breakpoint at current line.")
  335.   (gud-def gud-remove "clear %l"  "\C-d" "Remove breakpoint at current line")
  336.   (gud-def gud-step   "step %p"      "\C-s" "Step one line with display.")
  337.   (gud-def gud-stepi  "stepi %p"  "\C-i" "Step one instruction with display.")
  338.   (gud-def gud-next   "next %p"      "\C-n" "Step one line (skip functions).")
  339.   (gud-def gud-cont   "cont"      "\C-r" "Continue with display.")
  340.   (gud-def gud-up     "up %p"      "<" "Up (numeric arg) stack frames.")
  341.   (gud-def gud-down   "down %p"      ">" "Down (numeric arg) stack frames.")
  342.   (gud-def gud-print  "print %e"  "\C-p" "Evaluate C expression at point.")
  343.  
  344.   (setq comint-prompt-regexp  "^[^)]*dbx) *")
  345.   (run-hooks 'dbx-mode-hook)
  346.   )
  347.  
  348. ;; ======================================================================
  349. ;; xdb (HP PARISC debugger) functions
  350.  
  351. ;;; History of argument lists passed to xdb.
  352. (defvar gud-xdb-history nil)
  353.  
  354. (defvar gud-xdb-directories nil
  355.   "*A list of directories that xdb should search for source code.
  356. If nil, only source files in the program directory
  357. will be known to xdb.
  358.  
  359. The file names should be absolute, or relative to the directory
  360. containing the executable being debugged.")
  361.  
  362. (defun gud-xdb-massage-args (file args)
  363.   (nconc (let ((directories gud-xdb-directories)
  364.            (result nil))
  365.        (while directories
  366.          (setq result (cons (car directories) (cons "-d" result)))
  367.          (setq directories (cdr directories)))
  368.        (nreverse (cons file result)))
  369.      args))
  370.  
  371. (defun gud-xdb-file-name (f)
  372.   "Transform a relative pathname to a full pathname in xdb mode"
  373.   (let ((result nil))
  374.     (if (file-exists-p f)
  375.         (setq result (expand-file-name f))
  376.       (let ((directories gud-xdb-directories))
  377.         (while directories
  378.           (let ((path (concat (car directories) "/" f)))
  379.             (if (file-exists-p path)
  380.                 (setq result (expand-file-name path)
  381.                       directories nil)))
  382.           (setq directories (cdr directories)))))
  383.     result))
  384.  
  385. ;; xdb does not print the lines all at once, so we have to accumulate them
  386. (defvar gud-xdb-accumulation "")
  387.  
  388. (defun gud-xdb-marker-filter (string)
  389.   (let (result)
  390.     (if (or (string-match comint-prompt-regexp string)
  391.             (string-match ".*\012" string))
  392.         (setq result (concat gud-xdb-accumulation string)
  393.               gud-xdb-accumulation "")
  394.       (setq gud-xdb-accumulation (concat gud-xdb-accumulation string)))
  395.     (if result
  396.         (if (or (string-match "\\([^\n \t:]+\\): [^:]+: \\([0-9]+\\):" result)
  397.                 (string-match "[^: \t]+:[ \t]+\\([^:]+\\): [^:]+: \\([0-9]+\\):"
  398.                               result))
  399.             (let ((line (string-to-int 
  400.                          (substring result (match-beginning 2) (match-end 2))))
  401.                   (file (gud-xdb-file-name
  402.                          (substring result (match-beginning 1) (match-end 1)))))
  403.               (if file
  404.                   (setq gud-last-frame (cons file line))))))
  405.     (or result "")))    
  406.                
  407. (defun gud-xdb-find-file (f)
  408.   (let ((realf (gud-xdb-file-name f)))
  409.     (if realf (find-file-noselect realf))))
  410.  
  411. ;;;###autoload
  412. (defun xdb (command-line)
  413.   "Run xdb on program FILE in buffer *gud-FILE*.
  414. The directory containing FILE becomes the initial working directory
  415. and source-file directory for your debugger.
  416.  
  417. You can set the variable 'gud-xdb-directories' to a list of program source
  418. directories if your program contains sources from more than one directory."
  419.   (interactive
  420.    (list (read-from-minibuffer "Run xdb (like this): "
  421.                    (if (consp gud-xdb-history)
  422.                    (car gud-xdb-history)
  423.                  "xdb ")
  424.                    nil nil
  425.                    '(gud-xdb-history . 1))))
  426.   (gud-overload-functions '((gud-massage-args . gud-xdb-massage-args)
  427.                 (gud-marker-filter . gud-xdb-marker-filter)
  428.                 (gud-find-file . gud-xdb-find-file)))
  429.  
  430.   (gud-common-init command-line)
  431.  
  432.   (gud-def gud-break  "b %f:%l"    "\C-b" "Set breakpoint at current line.")
  433.   (gud-def gud-tbreak "b %f:%l\\t" "\C-t"
  434.            "Set temporary breakpoint at current line.")
  435.   (gud-def gud-remove "db"         "\C-d" "Remove breakpoint at current line")
  436.   (gud-def gud-step   "s %p"       "\C-s" "Step one line with display.")
  437.   (gud-def gud-next   "S %p"       "\C-n" "Step one line (skip functions).")
  438.   (gud-def gud-cont   "c"       "\C-r" "Continue with display.")
  439.   (gud-def gud-up     "up %p"       "<"    "Up (numeric arg) stack frames.")
  440.   (gud-def gud-down   "down %p"       ">"    "Down (numeric arg) stack frames.")
  441.   (gud-def gud-finish "bu\\t"      "\C-f" "Finish executing current function.")
  442.   (gud-def gud-print  "p %e"       "\C-p" "Evaluate C expression at point.")
  443.  
  444.   (setq comint-prompt-regexp  "^>")
  445.   (make-local-variable 'gud-xdb-accumulation)
  446.   (setq gud-xdb-accumulation "")
  447.   (run-hooks 'xdb-mode-hook))
  448.  
  449. ;;
  450. ;; End of debugger-specific information
  451. ;;
  452.  
  453. ;;; When we send a command to the debugger via gud-call, it's annoying
  454. ;;; to see the command and the new prompt inserted into the debugger's
  455. ;;; buffer; we have other ways of knowing the command has completed.
  456. ;;;
  457. ;;; If the buffer looks like this:
  458. ;;; --------------------
  459. ;;; (gdb) set args foo bar
  460. ;;; (gdb) -!-
  461. ;;; --------------------
  462. ;;; (the -!- marks the location of point), and we type `C-x SPC' in a
  463. ;;; source file to set a breakpoint, we want the buffer to end up like
  464. ;;; this:
  465. ;;; --------------------
  466. ;;; (gdb) set args foo bar
  467. ;;; Breakpoint 1 at 0x92: file make-docfile.c, line 49.
  468. ;;; (gdb) -!-
  469. ;;; --------------------
  470. ;;; Essentially, the old prompt is deleted, and the command's output
  471. ;;; and the new prompt take its place.
  472. ;;;
  473. ;;; Not echoing the command is easy enough; you send it directly using
  474. ;;; process-send-string, and it never enters the buffer.  However,
  475. ;;; getting rid of the old prompt is trickier; you don't want to do it
  476. ;;; when you send the command, since that will result in an annoying
  477. ;;; flicker as the prompt is deleted, redisplay occurs while Emacs
  478. ;;; waits for a response from the debugger, and the new prompt is
  479. ;;; inserted.  Instead, we'll wait until we actually get some output
  480. ;;; from the subprocess before we delete the prompt.  If the command
  481. ;;; produced no output other than a new prompt, that prompt will most
  482. ;;; likely be in the first chunk of output received, so we will delete
  483. ;;; the prompt and then replace it with an identical one.  If the
  484. ;;; command produces output, the prompt is moving anyway, so the
  485. ;;; flicker won't be annoying.
  486. ;;;
  487. ;;; So - when we want to delete the prompt upon receipt of the next
  488. ;;; chunk of debugger output, we position gud-delete-prompt-marker at
  489. ;;; the start of the prompt; the process filter will notice this, and
  490. ;;; delete all text between it and the process output marker.  If
  491. ;;; gud-delete-prompt-marker points nowhere, we leave the current
  492. ;;; prompt alone.
  493. (defvar gud-delete-prompt-marker nil)
  494.  
  495.  
  496. (defun gud-mode ()
  497.   "Major mode for interacting with an inferior debugger process.
  498.  
  499.    You start it up with one of the commands M-x gdb, M-x sdb, M-x dbx,
  500. or M-x xdb.  Each entry point finishes by executing a hook; `gdb-mode-hook',
  501. `sdb-mode-hook', `dbx-mode-hook' or `xdb-mode-hook' respectively.
  502.  
  503. After startup, the following commands are available in both the GUD
  504. interaction buffer and any source buffer GUD visits due to a breakpoint stop
  505. or step operation:
  506.  
  507. \\[gud-break] sets a breakpoint at the current file and line.  In the
  508. GUD buffer, the current file and line are those of the last breakpoint or
  509. step.  In a source buffer, they are the buffer's file and current line.
  510.  
  511. \\[gud-remove] removes breakpoints on the current file and line.
  512.  
  513. \\[gud-refresh] displays in the source window the last line referred to
  514. in the gud buffer.
  515.  
  516. \\[gud-step], \\[gud-next], and \\[gud-stepi] do a step-one-line,
  517. step-one-line (not entering function calls), and step-one-instruction
  518. and then update the source window with the current file and position.
  519. \\[gud-cont] continues execution.
  520.  
  521. \\[gud-print] tries to find the largest C lvalue or function-call expression
  522. around point, and sends it to the debugger for value display.
  523.  
  524. The above commands are common to all supported debuggers except xdb which
  525. does not support stepping instructions.
  526.  
  527. Under gdb, sdb and xdb, \\[gud-tbreak] behaves exactly like \\[gud-break],
  528. except that the breakpoint is temporary; that is, it is removed when
  529. execution stops on it.
  530.  
  531. Under gdb, dbx, and xdb, \\[gud-up] pops up through an enclosing stack
  532. frame.  \\[gud-down] drops back down through one.
  533.  
  534. If you are using gdb or xdb, \\[gud-finish] runs execution to the return from
  535. the current function and stops.
  536.  
  537. All the keystrokes above are accessible in the GUD buffer
  538. with the prefix C-c, and in all buffers through the prefix C-x C-a.
  539.  
  540. All pre-defined functions for which the concept make sense repeat
  541. themselves the appropriate number of times if you give a prefix
  542. argument.
  543.  
  544. You may use the `gud-def' macro in the initialization hook to define other
  545. commands.
  546.  
  547. Other commands for interacting with the debugger process are inherited from
  548. comint mode, which see."
  549.   (interactive)
  550.   (comint-mode)
  551.   (setq major-mode 'gud-mode)
  552.   (setq mode-name "Debugger")
  553.   (setq mode-line-process '(": %s"))
  554.   (use-local-map (copy-keymap comint-mode-map))
  555.   (make-local-variable 'gud-last-frame)
  556.   (setq gud-last-frame nil)
  557.   (make-local-variable 'comint-prompt-regexp)
  558.   (make-local-variable 'gud-delete-prompt-marker)
  559.   (setq gud-delete-prompt-marker (make-marker))
  560.   (run-hooks 'gud-mode-hook)
  561. )
  562.  
  563. (defvar gud-comint-buffer nil)
  564.  
  565. ;; Chop STRING into words separated by SPC or TAB and return a list of them.
  566. (defun gud-chop-words (string)
  567.   (let ((i 0) (beg 0)
  568.     (len (length string))
  569.     (words nil))
  570.     (while (< i len)
  571.       (if (memq (aref string i) '(?\t ? ))
  572.       (progn
  573.         (setq words (cons (substring string beg i) words)
  574.           beg (1+ i))
  575.         (while (and (< beg len) (memq (aref string beg) '(?\t ? )))
  576.           (setq beg (1+ beg)))
  577.         (setq i (1+ beg)))
  578.     (setq i (1+ i))))
  579.     (if (< beg len)
  580.     (setq words (cons (substring string beg) words)))
  581.     (nreverse words)))
  582.  
  583. ;; Perform initializations common to all debuggers.
  584. (defun gud-common-init (command-line)
  585.   (let* ((words (gud-chop-words command-line))
  586.      (program (car words))
  587.      (file-word (let ((w (cdr words)))
  588.               (while (and w (= ?- (aref (car w) 0)))
  589.             (setq w (cdr w)))
  590.               (car w)))
  591.      (args (delq file-word (cdr words)))
  592.      (file (expand-file-name file-word))
  593.      (filepart (file-name-nondirectory file)))
  594.       (switch-to-buffer (concat "*gud-" filepart "*"))
  595.       (setq default-directory (file-name-directory file))
  596.       (or (bolp) (newline))
  597.       (insert "Current directory is " default-directory "\n")
  598.       (apply 'make-comint (concat "gud-" filepart) program nil
  599.          (gud-massage-args file args)))
  600.   (gud-mode)
  601.   (set-process-filter (get-buffer-process (current-buffer)) 'gud-filter)
  602.   (set-process-sentinel (get-buffer-process (current-buffer)) 'gud-sentinel)
  603.   (gud-set-buffer)
  604.   )
  605.  
  606. (defun gud-set-buffer ()
  607.   (cond ((eq major-mode 'gud-mode)
  608.     (setq gud-comint-buffer (current-buffer)))))
  609.  
  610. ;; These functions are responsible for inserting output from your debugger
  611. ;; into the buffer.  The hard work is done by the method that is
  612. ;; the value of gud-marker-filter.
  613.  
  614. (defun gud-filter (proc string)
  615.   ;; Here's where the actual buffer insertion is done
  616.   (let ((inhibit-quit t))
  617.     (save-excursion
  618.       (set-buffer (process-buffer proc))
  619.       (let (moving output-after-point)
  620.     (save-excursion
  621.       (goto-char (process-mark proc))
  622.       ;; If we have been so requested, delete the debugger prompt.
  623.       (if (marker-buffer gud-delete-prompt-marker)
  624.           (progn
  625.         (delete-region (point) gud-delete-prompt-marker)
  626.         (set-marker gud-delete-prompt-marker nil)))
  627.       (insert-before-markers (gud-marker-filter string))
  628.       (setq moving (= (point) (process-mark proc)))
  629.       (setq output-after-point (< (point) (process-mark proc)))
  630.       ;; Check for a filename-and-line number.
  631.       ;; Don't display the specified file
  632.       ;; unless (1) point is at or after the position where output appears
  633.       ;; and (2) this buffer is on the screen.
  634.       (if (and gud-last-frame
  635.            (not output-after-point)
  636.            (get-buffer-window (current-buffer)))
  637.           (gud-display-frame)))
  638.     (if moving (goto-char (process-mark proc)))))))
  639.  
  640. (defun gud-sentinel (proc msg)
  641.   (cond ((null (buffer-name (process-buffer proc)))
  642.      ;; buffer killed
  643.      ;; Stop displaying an arrow in a source file.
  644.      (setq overlay-arrow-position nil)
  645.      (set-process-buffer proc nil))
  646.     ((memq (process-status proc) '(signal exit))
  647.      ;; Stop displaying an arrow in a source file.
  648.      (setq overlay-arrow-position nil)
  649.      ;; Fix the mode line.
  650.      (setq mode-line-process
  651.            (concat ": "
  652.                (symbol-name (process-status proc))))
  653.      (let* ((obuf (current-buffer)))
  654.        ;; save-excursion isn't the right thing if
  655.        ;;  process-buffer is current-buffer
  656.        (unwind-protect
  657.            (progn
  658.          ;; Write something in *compilation* and hack its mode line,
  659.          (set-buffer (process-buffer proc))
  660.          ;; Force mode line redisplay soon
  661.          (set-buffer-modified-p (buffer-modified-p))
  662.          (if (eobp)
  663.              (insert ?\n mode-name " " msg)
  664.            (save-excursion
  665.              (goto-char (point-max))
  666.              (insert ?\n mode-name " " msg)))
  667.          ;; If buffer and mode line will show that the process
  668.          ;; is dead, we can delete it now.  Otherwise it
  669.          ;; will stay around until M-x list-processes.
  670.          (delete-process proc))
  671.          ;; Restore old buffer, but don't restore old point
  672.          ;; if obuf is the gud buffer.
  673.          (set-buffer obuf))))))
  674.  
  675. (defun gud-display-frame ()
  676.   "Find and obey the last filename-and-line marker from the debugger.
  677. Obeying it means displaying in another window the specified file and line."
  678.   (interactive)
  679.   (if gud-last-frame
  680.    (progn
  681.      (gud-set-buffer)
  682.      (gud-display-line (car gud-last-frame) (cdr gud-last-frame))
  683.      (setq gud-last-last-frame gud-last-frame
  684.        gud-last-frame nil))))
  685.  
  686. ;; Make sure the file named TRUE-FILE is in a buffer that appears on the screen
  687. ;; and that its line LINE is visible.
  688. ;; Put the overlay-arrow on the line LINE in that buffer.
  689. ;; Most of the trickiness in here comes from wanting to preserve the current
  690. ;; region-restriction if that's possible.  We use an explicit display-buffer
  691. ;; to get around the fact that this is called inside a save-excursion.
  692.  
  693. (defun gud-display-line (true-file line)
  694.   (let* ((buffer (gud-find-file true-file))
  695.      (window (display-buffer buffer))
  696.      (pos))
  697. ;;;    (if (equal buffer (current-buffer))
  698. ;;;    nil
  699. ;;;      (setq buffer-read-only nil))
  700.     (save-excursion
  701. ;;;      (setq buffer-read-only t)
  702.       (set-buffer buffer)
  703.       (save-restriction
  704.     (widen)
  705.     (goto-line line)
  706.     (setq pos (point))
  707.     (setq overlay-arrow-string "=>")
  708.     (or overlay-arrow-position
  709.         (setq overlay-arrow-position (make-marker)))
  710.     (set-marker overlay-arrow-position (point) (current-buffer)))
  711.       (cond ((or (< pos (point-min)) (> pos (point-max)))
  712.          (widen)
  713.          (goto-char pos))))
  714.     (set-window-point window overlay-arrow-position)))
  715.  
  716. ;;; The gud-call function must do the right thing whether its invoking
  717. ;;; keystroke is from the GUD buffer itself (via major-mode binding)
  718. ;;; or a C buffer.  In the former case, we want to supply data from
  719. ;;; gud-last-frame.  Here's how we do it:
  720.  
  721. (defun gud-format-command (str arg)
  722.   (let ((insource (not (eq (current-buffer) gud-comint-buffer))))
  723.     (if (string-match "\\(.*\\)%f\\(.*\\)" str)
  724.     (progn
  725.       (setq str (concat
  726.              (substring str (match-beginning 1) (match-end 1))
  727.              (file-name-nondirectory (if insource
  728.                          (buffer-file-name)
  729.                            (car gud-last-frame)))
  730.              (substring str (match-beginning 2) (match-end 2))))))
  731.     (if (string-match "\\(.*\\)%l\\(.*\\)" str)
  732.     (progn
  733.       (setq str (concat
  734.              (substring str (match-beginning 1) (match-end 1))
  735.              (if insource
  736.              (save-excursion
  737.                (beginning-of-line)
  738.                (save-restriction (widen) 
  739.                          (1+ (count-lines 1 (point)))))
  740.                (cdr gud-last-frame))
  741.              (substring str (match-beginning 2) (match-end 2))))))
  742.     (if (string-match "\\(.*\\)%e\\(.*\\)" str)
  743.     (progn
  744.       (setq str (concat
  745.              (substring str (match-beginning 1) (match-end 1))
  746.              (find-c-expr)
  747.              (substring str (match-beginning 2) (match-end 2))))))
  748.     (if (string-match "\\(.*\\)%a\\(.*\\)" str)
  749.     (progn
  750.       (setq str (concat
  751.              (substring str (match-beginning 1) (match-end 1))
  752.              (gud-read-address)
  753.              (substring str (match-beginning 2) (match-end 2))))))
  754.     (if (string-match "\\(.*\\)%p\\(.*\\)" str)
  755.     (progn
  756.       (setq str (concat
  757.              (substring str (match-beginning 1) (match-end 1))
  758.              (if arg (int-to-string arg) "")
  759.              (substring str (match-beginning 2) (match-end 2))))))
  760.     )
  761.   str
  762.   )
  763.  
  764. (defun gud-read-address ()
  765.   "Return a string containing the core-address found in the buffer at point."
  766.   (save-excursion
  767.     (let ((pt (point)) found begin)
  768.       (setq found (if (search-backward "0x" (- pt 7) t) (point)))
  769.       (cond
  770.        (found (forward-char 2)
  771.           (buffer-substring found
  772.                 (progn (re-search-forward "[^0-9a-f]")
  773.                        (forward-char -1)
  774.                        (point))))
  775.        (t (setq begin (progn (re-search-backward "[^0-9]") 
  776.                  (forward-char 1)
  777.                  (point)))
  778.       (forward-char 1)
  779.       (re-search-forward "[^0-9]")
  780.       (forward-char -1)
  781.       (buffer-substring begin (point)))))))
  782.  
  783. (defun gud-call (fmt &optional arg)
  784.   (let ((msg (gud-format-command fmt arg)))
  785.     (message "Command: %s" msg)
  786.     (sit-for 0)
  787.     (gud-basic-call msg)))
  788.  
  789. (defun gud-basic-call (command)
  790.   "Invoke the debugger COMMAND displaying source in other window."
  791.   (interactive)
  792.   (gud-set-buffer)
  793.   (let ((command (concat command "\n"))
  794.     (proc (get-buffer-process gud-comint-buffer)))
  795.  
  796.     ;; Arrange for the current prompt to get deleted.
  797.     (save-excursion
  798.       (set-buffer gud-comint-buffer)
  799.       (goto-char (process-mark proc))
  800.       (beginning-of-line)
  801.       (if (looking-at comint-prompt-regexp)
  802.       (set-marker gud-delete-prompt-marker (point))))
  803.     (process-send-string proc command)))
  804.  
  805. (defun gud-refresh (&optional arg)
  806.   "Fix up a possibly garbled display, and redraw the arrow."
  807.   (interactive "P")
  808.   (recenter arg)
  809.   (or gud-last-frame (setq gud-last-frame gud-last-last-frame))
  810.   (gud-display-frame))
  811.  
  812. ;;; Code for parsing expressions out of C code.  The single entry point is
  813. ;;; find-c-expr, which tries to return an lvalue expression from around point.
  814. ;;;
  815. ;;; The rest of this file is a hacked version of gdbsrc.el by
  816. ;;; Debby Ayers <ayers@asc.slb.com>,
  817. ;;; Rich Schaefer <schaefer@asc.slb.com> Schlumberger, Austin, Tx.
  818.  
  819. (defun find-c-expr ()
  820.   "Returns the C expr that surrounds point."
  821.   (interactive)
  822.   (save-excursion
  823.     (let ((p) (expr) (test-expr))
  824.       (setq p (point))
  825.       (setq expr (expr-cur))
  826.       (setq test-expr (expr-prev))
  827.       (while (expr-compound test-expr expr)
  828.     (setq expr (cons (car test-expr) (cdr expr)))
  829.     (goto-char (car expr))
  830.     (setq test-expr (expr-prev)))
  831.       (goto-char p)
  832.       (setq test-expr (expr-next))
  833.       (while (expr-compound expr test-expr)
  834.     (setq expr (cons (car expr) (cdr test-expr)))
  835.     (setq test-expr (expr-next))
  836.     )
  837.       (buffer-substring (car expr) (cdr expr)))))
  838.  
  839. (defun expr-cur ()
  840.   "Returns the expr that point is in; point is set to beginning of expr.
  841. The expr is represented as a cons cell, where the car specifies the point in
  842. the current buffer that marks the beginning of the expr and the cdr specifies 
  843. the character after the end of the expr."
  844.   (let ((p (point)) (begin) (end))
  845.     (expr-backward-sexp)
  846.     (setq begin (point))
  847.     (expr-forward-sexp)
  848.     (setq end (point))
  849.     (if (>= p end) 
  850.     (progn
  851.      (setq begin p)
  852.      (goto-char p)
  853.      (expr-forward-sexp)
  854.      (setq end (point))
  855.      )
  856.       )
  857.     (goto-char begin)
  858.     (cons begin end)))
  859.  
  860. (defun expr-backward-sexp ()
  861.   "Version of `backward-sexp' that catches errors."
  862.   (condition-case nil
  863.       (backward-sexp)
  864.     (error t)))
  865.  
  866. (defun expr-forward-sexp ()
  867.   "Version of `forward-sexp' that catches errors."
  868.   (condition-case nil
  869.      (forward-sexp)
  870.     (error t)))
  871.  
  872. (defun expr-prev ()
  873.   "Returns the previous expr, point is set to beginning of that expr.
  874. The expr is represented as a cons cell, where the car specifies the point in
  875. the current buffer that marks the beginning of the expr and the cdr specifies 
  876. the character after the end of the expr"
  877.   (let ((begin) (end))
  878.     (expr-backward-sexp)
  879.     (setq begin (point))
  880.     (expr-forward-sexp)
  881.     (setq end (point))
  882.     (goto-char begin)
  883.     (cons begin end)))
  884.  
  885. (defun expr-next ()
  886.   "Returns the following expr, point is set to beginning of that expr.
  887. The expr is represented as a cons cell, where the car specifies the point in
  888. the current buffer that marks the beginning of the expr and the cdr specifies 
  889. the character after the end of the expr."
  890.   (let ((begin) (end))
  891.     (expr-forward-sexp)
  892.     (expr-forward-sexp)
  893.     (setq end (point))
  894.     (expr-backward-sexp)
  895.     (setq begin (point))
  896.     (cons begin end)))
  897.  
  898. (defun expr-compound-sep (span-start span-end)
  899.   "Returns '.' for '->' & '.', returns ' ' for white space,
  900. returns '?' for other punctuation."
  901.   (let ((result ? )
  902.     (syntax))
  903.     (while (< span-start span-end)
  904.       (setq syntax (char-syntax (char-after span-start)))
  905.       (cond
  906.        ((= syntax ? ) t)
  907.        ((= syntax ?.) (setq syntax (char-after span-start))
  908.     (cond 
  909.      ((= syntax ?.) (setq result ?.))
  910.      ((and (= syntax ?-) (= (char-after (+ span-start 1)) ?>))
  911.       (setq result ?.)
  912.       (setq span-start (+ span-start 1)))
  913.      (t (setq span-start span-end)
  914.         (setq result ??)))))
  915.       (setq span-start (+ span-start 1)))
  916.     result))
  917.  
  918. (defun expr-compound (first second)
  919.   "Non-nil if concatenating FIRST and SECOND makes a single C token.
  920. The two exprs are represented as a cons cells, where the car 
  921. specifies the point in the current buffer that marks the beginning of the 
  922. expr and the cdr specifies the character after the end of the expr.
  923. Link exprs of the form:
  924.       Expr -> Expr
  925.       Expr . Expr
  926.       Expr (Expr)
  927.       Expr [Expr]
  928.       (Expr) Expr
  929.       [Expr] Expr"
  930.   (let ((span-start (cdr first))
  931.     (span-end (car second))
  932.     (syntax))
  933.     (setq syntax (expr-compound-sep span-start span-end))
  934.     (cond
  935.      ((= (car first) (car second)) nil)
  936.      ((= (cdr first) (cdr second)) nil)
  937.      ((= syntax ?.) t)
  938.      ((= syntax ? )
  939.      (setq span-start (char-after (- span-start 1)))
  940.      (setq span-end (char-after span-end))
  941.      (cond
  942.       ((= span-start ?) ) t )
  943.       ((= span-start ?] ) t )
  944.           ((= span-end ?( ) t )
  945.       ((= span-end ?[ ) t )
  946.       (t nil))
  947.      )
  948.      (t nil))))
  949.  
  950. (provide 'gud)
  951.  
  952. ;;; gud.el ends here
  953.